PDFMakerAPIを使ってパスワード付きPDFを作成する

COM AddinのPDFMakerをスクリプトで操作してみる

OfficeのファイルをPDFに変換する方法はいろいろありますが、よく使われるものとして、仮想プリンタ(Adobe PDF)を使う方法と、アドインのAcrobat PDFMakerを使う方法があります。

特にワードをはじめとするOfficeファイルをPDFに変換するときには、PDFMakerを使うとみだしからしおりを作ったり、リンクをそのまま活かしたりと、高品質なPDFを作れます。パスワードを設定したPDFも作れます。

VBAをつかってPDFファイルを作るには、デフォルトのプリンタを仮想プリンタ(Adobe PDF)に設定して印刷させたり、PostScriptファイルを作って、Acrobat DistillerライブラリのFileToPDFメソッドを使う方法がよく知られています。

• Acrobat Distiller API Reference – Adobe Partners
• VBでのAutomation Eventの処理方法

しかし、せっかくアドインがあるのだから、ここは、PDFMakerを使ってVBAでPDFを作る方法にトライです。
今回の記事では、PDFMakerAPI 1.0 Type Library を単独で使って、VBAでPDFファイルを作成するサンプルスクリプトとその概要を示します。その後、他の２つのライブラリ AdobePDFMakerForOffice と AdobePDFMakerX について若干言及しつつ、最後に資料としてPDFMAKERAPILibのPDFMakerSettings列挙体とsecuritySettingsクラスのプロパティ、それにAdobePDFMakerForOfficeのISettingsクラスのプロパティをオブジェクトブラウザから転載します。
ただし、この記事で述べる方法は、Adobeの公式なドキュメントもなくサポート対象外なので、動作保証もありません。自己責任で。

動作確認環境

• OS windows XP SP3
• Word 2002 SP3
• Excel 2002 SP3
• Access 2002 SP3

私のPC環境では、Wordのメニューバーに「Adobe PDF」があり、そのメニューは次のようになっています。

設定メニューは次のとおり。
Word。
タブ1

タブ2

タブ3

タブ4

Excelでは次のとおり。
メニューバー

タブ1

タブ2

Officeのアプリケーションによって、設定項目が違います。

この環境のPDFMakerは、Docuworksと同時にインストールされている様なので、一般的な環境とは若干違うかもしれません。

VBAから単独で使えるのは PDFMakerAPI ぐらいか？

※一応、AdobePDFMakerForOfficeも使えます。

PC内にあるAdobeのものらしきライブラリをいろいろ試してみました。私の環境では、PDFMaker関連と思われるライブラリは、次の３つがあります。

• PDFMakerAPI 1.0 Type Library(PDFMakerAPI.tlb)
• AdobePDFMakerX(AdobePDFMakerX.tlb)
• AdobePDFMakerForOffice(AcrobatPDFMakerForOffice.tlb)

PDFMakerAPI.tlbとAdobePDFMakerX.tlbは C:\Program Files\Adobe\Acrobat 8.0\PDFMaker\Common に、

AcrobatPDFMakerForOffice.tlbは C:\Program Files\Adobe\Acrobat 8.0\PDFMaker\Office にありました。

名称から察するに、PDFMakerの本体がPDFMakerAPIでそのラッパーがAdobePDFMakerX、Office用のオプションがAdobePDFMakerForOfficeってとこでしょうか。勝手な推測です。

補足ですが、C:\Program Files\Adobe\Acrobat 8.0\PDFMaker\Common フォルダには PDFMakerAPI.dll というファイルもあり、プロパティを開くと、PDFMakerAPI Module 8.1.0.0 となっていて、著作権の項目は、Copyright 1984-2007 Adobe Systems Incorporated and its licensors. All rights reserved. と記されています。

PDFMakerAPI 1.0 Type Libraryの PDFMakerApp オブジェクトを使ってPDFを作る

PDFMakerAPI 1.0 Type Library 内のPDFMakerApp オブジェクトの CreatePDF メソッドを使って、PDFファイルを作ります。
ただし、この方法にもいくつか注意点があります。
まず、既に開いているファイルのPDFは作れません。CreatePDFメソッドの第１引数　srcFilePathに指定したファイルが開いていると、CreatePDFメソッドは　kPDFMErrorOpeningFile (= -8 (&HFFFFFFF8))を返してエラーになります。
また、このスクリプトをWordファイルで走らせたときは、他のWordファイルからPDFを作ると、スクリプトがそのWordファイルを閉じるときに「このファイルはすでに開かれているため、保存できません」エラーが出ます。

CreatePDFメソッドを使うと、
対応したアプリケーションを立ち上げる→ファイルを開く→PDFファイルを作る→ファイルを閉じる→アプリケーションを閉じる
の一連の作業をするからでしょう。
ひょっとしたら、PDFMAKERAPILibライブラリ内の PDFMakerDriver オブジェクトの一連のメソッドが動いているのかもしれません。

なので、この方法がとれるのは、

• Excelのファイルに記述して、WordファイルからPDFを作る。
• Wordのファイルに記述して、ExcelファイルからPDFを作る。
• Accessに記述して、WordやExcelファイルからPDFを作る。

といったところでしょうか。

サンプルスクリプト

このサンプルスクリプトでは、srcFilePathで指定したファイルを、pdfFilePath指定したPDFファイルに変換します。PDF変換のオプションとして設定した項目は、以下のとおり。

セキュリティ関連

• ファイルを開く時のパスワードは「0000」
• 印刷は不許可とし、権限設定を変更する時のパスワードは「1111」

しおりやリンクなど

• PDFファイルにしおりを追加
• 文書情報を追加

Sub PDFMakerAPI_test()
'===============================================================
'自身のアプリケーション以外のファイルをPDFに変換する際は、有用。
'参照設定　PDFMakerAPI 1.0 Type Library(PDFMakerAPI.tlb)
'convert closed office file to PDF with PDFMAKERAPILib
'===============================================================
Dim myPDFMakerApp As PDFMAKERAPILib.PDFMakerApp
Dim myConversionSettings As PDFMAKERAPILib.ConversionSettings   '変換設定
Dim mySecuritySettings As PDFMAKERAPILib.securitySettings   'セキュリティ設定
Dim srcFilePath As String, pdfFilePath As String    'ファイルパス
Dim myMsg As String
Dim settingsFile As String
Dim appType As Long
Dim bitField  As Long
Dim settings As Long
Dim PDFMRetVals As Long
    
    srcFilePath = "D:\test.doc" 'input office file
'    srcFilePath = "D:\test.xls"
    pdfFilePath = "D:\test.pdf" 'output PDF file

    'set PDFMakerApp,ConversionSettings and SecuritySettings objects
    Set myPDFMakerApp = New PDFMAKERAPILib.PDFMakerApp
    Set myConversionSettings = New PDFMAKERAPILib.ConversionSettings
    Set mySecuritySettings = myConversionSettings.GetSecuritySettings   'Get SecuritySettings
    
        'Get File Application Type
        appType = myPDFMakerApp.GetSupportedAppType(srcFilePath)
    
        'Make Security Parameters
        With mySecuritySettings
            'Set Opening Password
            .OpenDocPasswd = "0000"
            .OpenDocPasswdNeeded = True
            
            'Set Printing Password
            .PrintingModeAllowed = kPrintingAllowedNone
            .PermsPasswd = "1111"
            .PermsPasswdNeeded = True
        End With
        
        With myConversionSettings
            .LoadDefaultSettings
            .GetAppConversionDefaults appType, bitField, settingsFile
            .GetConversionParameters settings               'If applied default setting,it returns -1
            
                'Show Conversion settings
                myMsg = "bitField : " & bitField & " &H" & Hex(bitField)
                myMsg = myMsg & vbCrLf & "settingsFile : " & settingsFile
                myMsg = myMsg & vbCrLf & "Defaultsettings : " & settings & " &H" & Hex(settings)
                
            'Set Security Paramaters
            .SetSecuritySettings mySecuritySettings
            
                'Make ConversionParamaters
                bitField = kCreateBookmarks + kCreateDocInfo + kCreateTextNotes
            
            'Set ConversionParameters
            .SetConversionParameters (bitField)
            
            'Check ConversionSettings
                myMsg = myMsg & vbCrLf & "bitField : " & bitField & " &H" & Hex(bitField)
            .GetConversionParameters settings
                myMsg = myMsg & vbCrLf & "settings : " & settings & " &H" & Hex(settings)
        End With
                
        'Get PDF!
        'return PDFMakerRetVals Enum
        PDFMRetVals = myPDFMakerApp.CreatePDF(srcFilePath, pdfFilePath, myConversionSettings)
                myMsg = myMsg & vbCrLf & "PDFMakerRetVals : " & PDFMRetVals & " &H" & Hex(PDFMRetVals)
        Debug.Print myMsg
    
    Set mySecuritySettings = Nothing
    Set myConversionSettings = Nothing
    Set myPDFMakerApp = Nothing
End Sub

作成したPDFファイルのプロパティ

ファイルを開くと、パスワードを求められる。

PDFを作成したアプリケーションは、「Word用Acrobat PDFMaker 8.1」となっています。

セキュリティタブの表示

文書のセキュリティの詳細情報

上記の制限内であれば、自由に使えそうです。

PDFMakerAPI 1.0 Type Library (PDFMakerAPI.tlb)について

参照設定でPDFMakerAPI 1.0 Type LibraryのチェックボックスをONにすると、オブジェクトブラウザでクラスやメソッドを参照できます。

オブジェクトブラウザで確認すると、このライブラリには５つのクラスがあります。

• ConversionSettings
• IDirectSink
• PDFMakerApp
• PDFMakerDriver
• securitySettings

興味のある方は実際にオブジェクトブラウザで確認していただくとして、PDF変換のメソッドはPDFMakerAppクラスにありそうです。

PDFMakerAppクラスには、次の５つメソッドがあります。

• CreatePDF　　　　(Create PDF)
• CreatePDFFromConfigXML　　　　(Create PDF From XML Config File)
• CreatePDFFromMultipleFiles　　　　(Create PDF from multiple files)
• CreatePDFFromObject　　　　(Create PDF from object within file)
• GetSupportedAppType

上記リストのカッコ内は、オブジェクトブラウザで示されている説明です。それぞれ名称どおりの働きをするのでしょうが、私はCreatePDFとGetSupportedAppTypeしか使っていません。

CreatePDFメソッドの定義は次のようになっています。

Function CreatePDF(srcFilePath As String, pdfFilePath As String, [pSettings], [bConvertSilent], [bShowProgress], [bConvertAsync], [pClientHandle]) As Long

返値はLong型となっており、使ってみると、PDFMakerRetVals 列挙型を返すようです。

第１引数のsrcFilePathには、PDFに変換するファイル　要はWordやExcelファイルのフルパス、第２引数のpdfFilePathには、出力するPDFファイルのフルパスを指定します。

第３引数のpSettingsには、ConversionSettings オブジェクトを指定します。第４引数以下は、私が使っている限りでは動作確認できませんでした。

ConversionSettings オブジェクトで変換設定する

PDFファイルに「しおり」や「みだし」をつけるかどうか、またパスワードの設定など、PDFの変換設定にはConversionSettings オブジェクトを使います。サンプルスクリプトで行った主な作業は以下のとおり。

1. ConversionSettingsオブジェクトにGetSecuritySettingsメソッドを適用して、securitySettingsオブジェクトを取得する。
2. securitySettings オブジェクトの各種プロパティを操作して、パスワードなどを設定する。
3. ConversionSettingsオブジェクトのSetSecuritySettings メソッドで、変更後の securitySettings オブジェクトを適用する。
4. ConversionSettingsオブジェクトのGetAppConversionDefaults メソッドで変換元ファイルの種類に応じた bitField を取得する。
5. bitFieldを任意に変更する（PDFMakerSettings 列挙型の和）。
6. SetConversionParameters メソッドで、変更後の bitFieldを適用する。

PDFのセキュリティ項目を変更するときに扱うsecuritySettings オブジェクトには１４のプロパティがあります。参考資料として下に一覧を示してあるので、ご覧ください。

内容はオブジェクトブラウザでも確認できますし、自動メンバ表示も動作しますので、プロパティ名とオブジェクトブラウザに表示される説明からどんな項目か、ほぼ見当がつくでしょう。

なお、オブジェクトブラウザに表示される securitySettings クラスの説明に

Structure containing the security settings (Second Tab of Conversion Settings Dialog)

とあるように、このプロパティはセキュリティタブの設定項目と対応しているようです。

サンプルスクリプトでも分かると思いますが、ファイルを開くときにパスワードを要求するときは、OpenDocPasswdNeeded に True を設定し、OpenDocPasswd にパスワードを設定します。今回は、「0000」としました。また、サンプルスクリプトでは印刷を不許可にして、権限設定を変更する際のパスワードを「1111」にしてあります。私のPCにはAdobe Readerしかインストールされていないので、権限パスワードは確認できていませんが。

PDF変換設定を変更する

PDFの変換設定を変更するには、ConversionSettings オブジェクトの SetConversionParameters メソッドを実行します。引数として長整数型 settings をとりますが、これは PDFMakerSettings 列挙型の和であり、足算結果を１６進数で解釈しているようです。

PDFMakerAPI 1.0 Type Libraryで変換設定を操作するときは、いちいちPDFMakerSettings 列挙型の和を指定しないといけないので、若干面倒です。

PDFMakerSettings 列挙型 の一覧も下の参考資料に示しましたので、ご覧ください。

全ての設定が使えるわけではない

おそらくいくつかのライブラリを組み合わせて使うことを想定しているものを、単体で使おうとしているので、思い通りに動作しないこともあります。

今回全ての設定を使い込んだわけでないのですが、少なくともExcelファイルをPDFに変換する際、kPromptForSheetSelection すなわち、「Excelのシートを確認するダイアログを表示する」をONにしても、ダイアログは表示されませんでした。Excelアプリケーションの標準ConversionParametersを読み込んで、値が&H8400017であることを確認しているのですが。

複数のワークシートを含んだブックを、今回の方法でPDFに変換すると、ファイルを開いた時にアクティブなワークシートだけがPDFに変換されます。

AdobePDFMakerForOfficeライブラリのPDFMakerオブジェクトを使ってPDFを作る

実は、PDFMakerAPIを単独で使うよりも、AdobePDFMakerForOfficeライブラリのPDFMakerオブジェクトと一緒に使う、下のサンプルスクリプトの方が使いやすい場面があるかもしれません。
変換設定の方法は、AdobePDFMakerForOfficeライブラリのISettingsオブジェクトの各プロパティを設定するだけ。
ただ、Officeの各アプリケーションを意識しないといけないのが、若干面倒かも。ま、お好みに応じて。

制限はPDFMakerAPIを単独で使うときと、ほぼ同じ。
以下に、いくつかサンプルスクリプトを示します。

WordのNormal.dotの標準モジュールに記述して、開いているファイルをPDF変換する

次に示すサンプルスクリプトは、Wordファイルに記述して起動すると、開いているWordファイルのPDFを同じフォルダに作成します。PDF Maker アドインの設定にかかわらず、PDFファイルには、ファイルを開く時のパスワード（0000）が設定されます。またPDFの作成後、PDFは表示されません。

Sub AdobePDFMakerForOffice_testSecurity()
'===============================================================
'アクティブなドキュメントをPDF変換するには、AdobePDFMakerForOfficeライブラリを使う。
'参照設定　PDFMakerAPI 1.0 Type Library(PDFMakerAPI.tlb)
'　　　　　AdobePDFMakerForOffice(AcrobatPDFMakerForOffice.tlb)
'convert active document to PDF with AdobePDFMakerForOffice
'===============================================================
Dim myPDFMaker As AdobePDFMakerForOffice.PDFMaker
Dim myISettings As AdobePDFMakerForOffice.ISettings
Dim myConversionSettings As PDFMAKERAPILib.ConversionSettings
Dim mySecuritySettings As PDFMAKERAPILib.securitySettings
Dim myObj As Variant
Dim pdfFilePath As String

'not saved document cannot be converted
If Not Application.ActiveDocument.Saved Then
    MsgBox "PDFに変換する前に、ファイルを保存してください。"
    Exit Sub
End If

'get PDFMaker COMAddIn Object
Set myPDFMaker = Nothing
For Each myObj In Application.COMAddIns
    If InStr(UCase(myObj.Description), "PDFMAKER") > 0 Then
        Set myPDFMaker = myObj.Object
        Exit For
    End If
Next

If myPDFMaker Is Nothing Then
    MsgBox "PDFMaker add-in が見つかりませんでした。", vbAbortRetryIgnore
    Exit Sub
End If

'set output PDF filepath
    pdfFilePath = Application.ActiveDocument.FullName
    pdfFilePath = Left(pdfFilePath, InStrRev(pdfFilePath, ".") - 1) & ".pdf"

'get SecuritySettings object and set security parameters (PassWord)
Set myConversionSettings = New PDFMAKERAPILib.ConversionSettings
Set mySecuritySettings = myConversionSettings.GetSecuritySettings
    mySecuritySettings.OpenDocPasswd = "0000"
    mySecuritySettings.OpenDocPasswdNeeded = True

'set Converion parameters and securitySettings object
    myPDFMaker.GetCurrentConversionSettings myISettings
    myISettings.OutputPDFFileName = pdfFilePath
    myISettings.ShouldShowProgressDialog = False
    myISettings.ViewPDFFile = False
    myISettings.securitySettings = mySecuritySettings
    
'create PDF
    myPDFMaker.CreatePDFEx myISettings, 0
    
Set myConversionSettings = Nothing
Set mySecuritySettings = Nothing
Set myPDFMaker = Nothing

End Sub

Accessの標準モジュールに記述して、WordファイルをPDF変換

Sub AdobePDFMakerForOffice_Word()
'===============================================================
'ドキュメントをPDF変換するには、AdobePDFMakerForOfficeライブラリを使う。
'参照設定　PDFMakerAPI 1.0 Type Library(PDFMakerAPI.tlb)
'　　　　　AdobePDFMakerForOffice(AcrobatPDFMakerForOffice.tlb)
'          Microsoft Word 10.0 Object Library
'convert a document to PDF with AdobePDFMakerForOffice
'===============================================================
Dim myPDFMaker As AdobePDFMakerForOffice.PDFMaker
Dim myISettings As AdobePDFMakerForOffice.ISettings
Dim myConversionSettings As PDFMAKERAPILib.ConversionSettings
Dim mySecuritySettings As PDFMAKERAPILib.securitySettings
Dim myObj As Variant
Dim wdFilePath As String
Dim pdfFilePath As String

Dim myWD As Word.Application
Set myWD = CreateObject("Word.Application")


'get PDFMaker COMAddIn Object
Set myPDFMaker = Nothing
For Each myObj In myWD.COMAddIns
    If InStr(UCase(myObj.Description), "PDFMAKER") > 0 Then
        Set myPDFMaker = myObj.Object
        Exit For
    End If
Next

If myPDFMaker Is Nothing Then
    MsgBox "PDFMaker add-in が見つかりませんでした。", vbAbortRetryIgnore
    Exit Sub
End If

'set filepath
    wdFilePath = "D:¥test.doc"
    pdfFilePath = "D:¥test.pdf"
    
    myWD.Documents.Open wdFilePath

'get SecuritySettings object and set security parameters (PassWord)
Set myConversionSettings = New PDFMAKERAPILib.ConversionSettings
Set mySecuritySettings = myConversionSettings.GetSecuritySettings
    mySecuritySettings.OpenDocPasswd = "0000"
    mySecuritySettings.OpenDocPasswdNeeded = True

'set Converion parameters and securitySettings object
    myPDFMaker.GetCurrentConversionSettings myISettings
    With myISettings
        .OutputPDFFileName = pdfFilePath
        .ShouldShowProgressDialog = False
        .ViewPDFFile = False
        .securitySettings = mySecuritySettings
    End With
    
'create PDF
    myPDFMaker.CreatePDFEx myISettings, 0
    
Set myConversionSettings = Nothing
Set mySecuritySettings = Nothing
Set myPDFMaker = Nothing

    myWD.Quit wdDoNotSaveChanges
Set myWD = Nothing

End Sub

Accessの標準モジュールに記述して、ExcelファイルをPDF変換

（全てのワークシートを変換する設定にしてあります。）

Sub AdobePDFMakerForOffice_Excel()
'===============================================================
'ドキュメントをPDF変換するには、AdobePDFMakerForOfficeライブラリを使う。
'参照設定　PDFMakerAPI 1.0 Type Library(PDFMakerAPI.tlb)
'　　　　　AdobePDFMakerForOffice(AcrobatPDFMakerForOffice.tlb)
'          Microsoft Excel 10.0 Object Library
'convert a document to PDF with AdobePDFMakerForOffice
'===============================================================
Dim myPDFMaker As AdobePDFMakerForOffice.PDFMaker
Dim myISettings As AdobePDFMakerForOffice.ISettings
Dim myConversionSettings As PDFMAKERAPILib.ConversionSettings
Dim mySecuritySettings As PDFMAKERAPILib.securitySettings
Dim myObj As Variant
Dim wdFilePath As String
Dim pdfFilePath As String

Dim myXls As Excel.Application
Set myXls = CreateObject("Excel.Application")


'get PDFMaker COMAddIn Object
Set myPDFMaker = Nothing
For Each myObj In myXls.COMAddIns
    If InStr(UCase(myObj.Description), "PDFMAKER") > 0 Then
        Set myPDFMaker = myObj.Object
        Exit For
    End If
Next

If myPDFMaker Is Nothing Then
    MsgBox "PDFMaker add-in が見つかりませんでした。", vbAbortRetryIgnore
    Exit Sub
End If

'set filepath
    wdFilePath = "D:¥test.doc"
    pdfFilePath = "D:¥test.pdf"
    
    myXls.Workbooks.Open wdFilePath

'get SecuritySettings object and set security parameters (PassWord)
Set myConversionSettings = New PDFMAKERAPILib.ConversionSettings
Set mySecuritySettings = myConversionSettings.GetSecuritySettings
    mySecuritySettings.OpenDocPasswd = "0000"
    mySecuritySettings.OpenDocPasswdNeeded = True

'set Converion parameters and securitySettings object
    myPDFMaker.GetCurrentConversionSettings myISettings
    With myISettings
        .OutputPDFFileName = pdfFilePath
        .ShouldShowProgressDialog = False
        .ViewPDFFile = False
        .PrintActivesheetOnly = False   '全てのワークシートを変換
        .PromptForSheetSelection = False '「Adobe PDF に含める Excel ワークシートを選択」ダイアログを非表示
        .securitySettings = mySecuritySettings
    End With
    
'create PDF
    myPDFMaker.CreatePDFEx myISettings, 0
    
Set myConversionSettings = Nothing
Set mySecuritySettings = Nothing
Set myPDFMaker = Nothing

    myXls.Quit
Set myXls = Nothing

End Sub

これらのスクリプトのポイントは、AdobePDFMakerForOffice.PDFMakerオブジェクトを、アプリケーションのCOMAddInsコレクションから参照しているところです。したがって、WordのNormal.dotの標準モジュールに記述するときは別として、AdobePDFMakerForOffice_WordやAdobePDFMakerForOffice_Excelのように、ほかのアプリケーションからPDF変換する時は、それぞれ変換するファイルのアプリケーションのインスタンスを明示的に作らなくてはいけません。
（既に開いているアプリケーションがあるなら、GetObject関数でそれを操作するのも一つの方法です。）

この、AdobePDFMakerForOfficeライブラリを使う方法は、Web上で見つけたコードに少し手を加えたものです。
ハック的な方法として出回っているのですが、変換元のファイルを明確に指定しずらい所や、特にワードの場合は他にインスタンスが開いているとNormal.dotの関係で思い通りの操作をするのが難しかったり（Wordのウィンドウを閉じられない）して、個人的にはあまり好みではありません。でも、コードとして分かりやすいのはこちらかな。

AdobePDFMakerX はうまく使えない（おまけ）

最後に残った AdobePDFMakerX ライブラリですが、これはどうにも活用できませんでした。

オブジェクトブラウザで見ている限りでは、オブジェクトの数も多く、差し込み印刷をPDFに変換するオブジェクトや、メール送信するオブジェクトもあるので、おそらくAdobePDFMakerXが活用できればいろいろできそうなのですが、どうにも思ったとおりに動かない。ひょっとしたら、いくつかのオブジェクトをうまく順番に使っていくとできるのかもしれません。誰か腕に覚えのある方、チャレンジしてみません？

読者の方のおかげです

実は、記事の公開当初、AdobePDFMakerForOfficeライブラリを使った方法は、CreatePDFExメソッドで異常終了しているようで、上手く動かないと書いていました。
その後、2013年2月下旬に、問い合わせフォームから、下記のようなメッセージをいただいたのです（一部抜粋）。

　さて、「私の環境では完璧には動きません。」とありましたが、「Wordファイルにコードを書いて、そのファイルのPDFを作る場合」に「myPDFMaker.CreatePDFExのところでスクリプトが異常終了」するのは当然のことと思われますが、如何でしょうか!?　というのは、WordファイルをPDFMakerでpdf化する過程では、pdf化するWordファイルを一度閉じて再度開くという操作が行われるので、その文書にPDFMakerを呼び出すVBAモジュールが組み込まれていると、PDFMakerでの処理が済んでVBAに制御が戻そうとしても戻せないからです。例えば、Normal.dotのようにWordアプリケーションが起動している間はずっと開かれたままのファイルにpdf化モジュールを組み込んでみてはどうでしょうか。多分、問題なくと動作すると思うのですが…　一度御試し下さい。因みに、当方ではそのような方法で問題なく動作しました。

いやー、全くそのとおり。一人でモンモンとやっていると、気づかないものです。
遅まきながら、2013年3月11日、後半を大幅に書き直しました。ご指摘、ありがとうございました。

こんなふうに、おかしなことを書いていることがあるかもしれないので、お気づきの際は about and comments から教えていただけると助かります。

参考資料

Enum PDFMakerSettings

Class securitySettings

Structure containing the security settings (Second Tab of Conversion Settings Dialog)

Class ISettings

---

---